Merge 6c88cb1158 into 6933c62ef2

pkgs/applications/editors/vim/plugins/cocPlugins.nix

@@ -24,6 +24,7 @@ let
     "coc-json"
     "coc-lists"
     "coc-markdownlint"
+    "coc-nginx"
     "coc-pairs"
     "coc-prettier"
     "coc-pyright"

pkgs/applications/editors/vim/plugins/nodePackagePlugins.nix

@@ -10,20 +10,13 @@ let
     "coc-ltex"
     "coc-tsserver"
     "coc-ultisnips"
-    "coc-nginx"
   ];
-
-  packageNameOverrides = {
-    "coc-nginx" = "@yaegassy/coc-nginx";
-  };
-
-  getPackageName = name: packageNameOverrides.${name} or name;
 in
 lib.genAttrs nodePackageNames (
   name:
   buildVimPlugin {
     pname = name;
-    inherit (nodePackages.${getPackageName name}) version meta;
-    src = "${nodePackages.${getPackageName name}}/lib/node_modules/${getPackageName name}";
+    inherit (nodePackages.${name}) version meta;
+    src = "${nodePackages.${name}}/lib/node_modules/${name}";
   }
 )

pkgs/by-name/co/coc-nginx/package.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  yarnConfigHook,
+  yarnBuildHook,
+  yarnInstallHook,
+  nodejs,
+  nix-update-script,
+  esbuild,
+  buildGoModule,
+}:
+let
+  esbuild' =
+    let
+      version = "0.16.17";
+    in
+    esbuild.override {
+      buildGoModule =
+        args:
+        buildGoModule (
+          args
+          // {
+            inherit version;
+            src = fetchFromGitHub {
+              owner = "evanw";
+              repo = "esbuild";
+              rev = "v${version}";
+              hash = "sha256-8L8h0FaexNsb3Mj6/ohA37nYLFogo5wXkAhGztGUUsQ=";
+            };
+            vendorHash = "sha256-+BfxCyg0KkDQpHt/wycy/8CTG6YBA/VJvJFhhzUnSiQ=";
+          }
+        );
+    };
+in
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "coc-nginx";
+  version = "0.5.0";
+
+  src = fetchFromGitHub {
+    owner = "yaegassy";
+    repo = "coc-nginx";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-9dca1YUQZCbzmGe+9qVJABCWZCGUUZDvtznMQEP/CCQ=";
+  };
+
+  yarnOfflineCache = fetchYarnDeps {
+    inherit (finalAttrs) src;
+    hash = "sha256-CBw2E93EWmBOCppj1gxYuAynHBZDJBPh58X099TP5mE=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    yarnInstallHook
+    nodejs
+    esbuild'
+  ];
+
+  env.ESBUILD_BINARY_PATH = lib.getExe esbuild';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "nginx-language-server extension for coc.nvim";
+    homepage = "https://github.com/yaegassy/coc-nginx";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+  };
+})

pkgs/by-name/co/code-theme-converter/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  yarnConfigHook,
+  yarnBuildHook,
+  yarnInstallHook,
+  nodejs,
+  nix-update-script,
+}:
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "code-theme-converter";
+  version = "1.2.1";
+
+  src = fetchFromGitHub {
+    owner = "tobiastimm";
+    repo = "code-theme-converter";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-b6b0s6FXyHwoAJnPTaLu9fMQJVpBSqfGBk/KqDbaK9U=";
+  };
+
+  yarnOfflineCache = fetchYarnDeps {
+    inherit (finalAttrs) src;
+    hash = "sha256-M8zLr/BPQfS50ZsTwN/YdJAlYUtS9edE/jh+l1wBqR8=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    yarnInstallHook
+    nodejs
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Convert any Visual Studio Code Theme to Sublime Text 3 or IntelliJ IDEA";
+    homepage = "https://github.com/tobiastimm/code-theme-converter";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+  };
+})

pkgs/by-name/co/commitlint/package.nix

@@ -0,0 +1,68 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  yarnConfigHook,
+  nodejs,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "commitlint";
+  version = "20.1.0";
+
+  src = fetchFromGitHub {
+    owner = "conventional-changelog";
+    repo = "commitlint";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-o8AnIewSmg8vRjs8LU6QwRyl2hMQ2iK5W7WL137treU=";
+  };
+
+  yarnOfflineCache = fetchYarnDeps {
+    inherit (finalAttrs) src;
+    hash = "sha256-Kg19sEgstrWj+JLzdZFnMeb0F5lFX3Z0VPNyiYPi6nY=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    nodejs
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    pkgs=("config-validator" "rules" "parse" "is-ignored" "lint"
+          "resolve-extends" "execute-rule" "load" "read" "types" "cli")
+    for p in "''${pkgs[@]}" ; do
+      cd @commitlint/$p/
+      yarn run tsc --build --force
+      cd ../..
+    done
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    yarn install --offline --production --ignore-scripts
+    mkdir -p $out/bin
+    mkdir -p $out/lib/node_modules/@commitlint/root
+    mv * $out/lib/node_modules/@commitlint/root/
+    ln -s $out/lib/node_modules/@commitlint/root/@commitlint/cli/cli.js $out/bin/commitlint
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/conventional-changelog/commitlint/releases/tag/v${finalAttrs.version}";
+    description = "Lint your commit messages";
+    homepage = "https://commitlint.js.org/";
+    license = lib.licenses.mit;
+    mainProgram = "commitlint";
+    maintainers = with lib.maintainers; [ pyrox0 ];
+  };
+})

pkgs/by-name/co/conventional-changelog-cli/package.nix

@@ -0,0 +1,68 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nodejs,
+  pnpm,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "conventional-changelog-cli";
+  version = "7.1.1";
+
+  src = fetchFromGitHub {
+    owner = "conventional-changelog";
+    repo = "conventional-changelog";
+    tag = "conventional-changelog-v${finalAttrs.version}";
+    hash = "sha256-Pgx5gM4SdSL6WCkStByA7AP2O96MjAjyeMOI+Lo2mt0=";
+  };
+
+  pnpmDeps = pnpm.fetchDeps {
+    inherit (finalAttrs) pname version src;
+    fetcherVersion = 2;
+    hash = "sha256-ZfG3F0J1hIhZlF2OadhVdbxhQrFcMYDG9gEXR04DgEI=";
+  };
+
+  nativeBuildInputs = [
+    nodejs
+    pnpm.configHook
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    pnpm run build
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/lib/node_modules/conventional-changelog/
+    mkdir $out/bin
+    mv * $out/lib/node_modules/conventional-changelog/
+    chmod +x $out/lib/node_modules/conventional-changelog/packages/conventional-changelog/dist/cli/index.js
+    ln -s $out/lib/node_modules/conventional-changelog/packages/conventional-changelog/dist/cli/index.js $out/bin/conventional-changelog
+    patchShebangs $out/bin/conventional-changelog
+
+    runHook postInstall
+  '';
+
+  postInstall = ''
+    substituteInPlace $out/lib/node_modules/conventional-changelog/packages/*/package.json \
+      --replace-warn '"exports": "./src/index.ts"' '"exports": "./dist/index.js"'
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/conventional-changelog/conventional-changelog/releases/tag/conventional-changelog-v${finalAttrs.version}";
+    description = "Generate a CHANGELOG from git metadata";
+    homepage = "https://github.com/conventional-changelog/conventional-changelog";
+    license = lib.licenses.isc;
+    maintainers = [ lib.maintainers.pyrox0 ];
+    mainProgram = "conventional-changelog";
+  };
+})

pkgs/by-name/di/diff2html-cli/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  yarnConfigHook,
+  yarnBuildHook,
+  yarnInstallHook,
+  nodejs,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "diff2html-cli";
+  version = "5.2.15";
+
+  src = fetchFromGitHub {
+    owner = "rtfpessoa";
+    repo = "diff2html-cli";
+    rev = finalAttrs.version;
+    hash = "sha256-aQoWn5n+xpYjhDQjw9v5HzWf/Hhmm6AK22OG4Ugq6Gk=";
+  };
+
+  postPatch = ''
+    substituteInPlace package.json \
+      --replace-fail "4.2.1" "${finalAttrs.version}";
+  '';
+
+  yarnOfflineCache = fetchYarnDeps {
+    inherit (finalAttrs) src;
+    hash = "sha256-9JkzWhsXUrjnMcDDJfqm+tZ+WV5j3CHJbpn9j7v/KLg=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    yarnInstallHook
+    nodejs
+  ];
+
+  meta = {
+    description = "Generate pretty HTML diffs from unified and git diff output in your terminal";
+    homepage = "https://diff2html.xyz#cli";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+    mainProgram = "diff2html";
+  };
+})

pkgs/by-name/js/json-diff/package.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+buildNpmPackage (finalAttrs: {
+  pname = "json-diff";
+  version = "1.0.6";
+
+  src = fetchFromGitHub {
+    owner = "andreyvit";
+    repo = "json-diff";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-b8CtttEmPUIuFba6yn0DhVsSM1RA8Jsl4+zGvk3EZ2s=";
+  };
+
+  npmDepsHash = "sha256-hpnmBD9fyudjc3dzxZ5L5mhkCfRbw7BaAHKGf76qVDU=";
+
+  npmBuildScript = "test";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Structural diff for JSON files";
+    homepage = "https://github.com/andreyvit/json-diff";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+    mainProgram = "json-diff";
+  };
+})

pkgs/by-name/ka/katex/package.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  yarn-berry,
+  nodejs,
+  makeBinaryWrapper,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "katex";
+  version = "0.16.25";
+
+  src = fetchFromGitHub {
+    owner = "katex";
+    repo = "katex";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-XwKjoXkn96YNxrBv2qcUSqKMtHxz9+levevc4Rz1SYw=";
+  };
+
+  offlineCache = yarn-berry.fetchYarnBerryDeps {
+    inherit (finalAttrs) src;
+    hash = "sha256-vPYzt+ZBbi1sR7T1I08f/syTnN8hnUTqH4fKCBiFIM0=";
+  };
+
+  nativeBuildInputs = [
+    yarn-berry.yarnBerryConfigHook
+    yarn-berry
+    nodejs
+    makeBinaryWrapper
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    yarn build
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    yarn config set nodeLinker "node-modules"
+    yarn install --mode=skip-build --inline-builds
+    mkdir -p $out/lib/node_modules/katex/
+    mkdir $out/bin
+    mv * $out/lib/node_modules/katex/
+    makeWrapper ${lib.getExe nodejs} $out/bin/katex \
+      --add-flags "$out/lib/node_modules/katex/cli.js" \
+      --set NODE_PATH "$out/lib/node_modules/katex/node_modules"
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/KaTeX/KaTeX/releases/tag/v${finalAttrs.version}";
+    description = "Render TeX to HTML";
+    homepage = "https://katex.org/";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.pyrox0 ];
+    mainProgram = "katex";
+  };
+})

pkgs/by-name/lo/localtunnel/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  yarnConfigHook,
+  yarnInstallHook,
+  nodejs,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "localtunnel";
+  version = "2.0.2";
+
+  src = fetchFromGitHub {
+    owner = "localtunnel";
+    repo = "localtunnel";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-6gEK1VjF25Kbe2drxbxUKDNJGqZ+OXgkulPkAkMR2+k=";
+  };
+
+  yarnOfflineCache = fetchYarnDeps {
+    inherit (finalAttrs) src;
+    hash = "sha256-zq9ygsKDU4lIsNxc6ovW+IXVztQoEaJAekzBrwCK7ik=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnInstallHook
+    nodejs
+  ];
+
+  updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/localtunnel/localtunnel/blob/v${finalAttrs.version}/CHANGELOG.md";
+    description = "CLI for localtunnel";
+    homepage = "https://localtunnel.me";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+    mainProgram = "lt";
+  };
+})

pkgs/by-name/nr/nrm/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nodejs,
+  pnpm,
+  makeBinaryWrapper,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "nrm";
+  version = "2.1.0";
+
+  src = fetchFromGitHub {
+    owner = "pana";
+    repo = "nrm";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-2P0dSZa17A3NslNatCx1edLnrcDtGGpOlk6srcvjL1Y=";
+  };
+
+  nativeBuildInputs = [
+    nodejs
+    pnpm.configHook
+    makeBinaryWrapper
+  ];
+
+  pnpmDeps = pnpm.fetchDeps {
+    inherit (finalAttrs) pname version src;
+    fetcherVersion = 2;
+    hash = "sha256-PENYS5xO2LwT3+TGl/wU2r0ALEj/JQfbkpf/0MJs0uw=";
+  };
+
+  buildPhase = ''
+    runHook preBuild
+
+    pnpm run build
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/lib/node_modules/nrm
+    mkdir $out/bin
+    mv * $out/lib/node_modules/nrm/
+    makeWrapper ${lib.getExe nodejs} $out/bin/nrm \
+      --add-flags "$out/lib/node_modules/nrm/dist/index.js" \
+      --set "NODE_PATH" "$out/lib/node_modules/nrm/node_modules"
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/Pana/nrm/releases/tag/v${finalAttrs.version}";
+    description = "Helps you switch between npm registries easily";
+    homepage = "https://github.com/Pana/nrm";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+    mainProgram = "nrm";
+  };
+})

pkgs/development/node-packages/aliases.nix

@@ -33,11 +33,13 @@ let
 in
 
 mapAliases {
+  "@antfu/ni" = pkgs.ni; # Added 2025-11-08
   "@antora/cli" = pkgs.antora; # Added 2023-05-06
   "@astrojs/language-server" = pkgs.astro-language-server; # Added 2024-02-12
   "@babel/cli" =
     throw "@babel/cli was removed because upstream highly suggests installing it in your project instead of globally."; # Added 2025-11-06
   "@bitwarden/cli" = pkgs.bitwarden-cli; # added 2023-07-25
+  "@commitlint/cli" = pkgs.commitlint; # Added 2025-11-08
   "@commitlint/config-conventional" =
     throw "@commitlint/config-conventional has been dropped, as it is a library and your JS project should lock it instead."; # added 2024-12-16
   "@emacs-eask/cli" = pkgs.eask; # added 2023-08-17
@@ -64,6 +66,7 @@ mapAliases {
   "@webassemblyjs/wasm-text-gen-1.11.1" = pkgs.wasm-text-gen; # Added 2025-11-06
   "@webassemblyjs/wast-refmt-1.11.1" = pkgs.wast-refmt; # Added 2025-11-06
   "@withgraphite/graphite-cli" = pkgs.graphite-cli; # added 2024-01-25
+  "@yaegassy/coc-nginx" = pkgs.coc-nginx; # Added 2025-11-08
   "@zwave-js/server" = pkgs.zwave-js-server; # Added 2023-09-09
   inherit (pkgs) autoprefixer; # added 2024-06-25
   inherit (pkgs) asar; # added 2023-08-26
@@ -127,10 +130,12 @@ mapAliases {
   inherit (pkgs) coc-wxml; # Added 2025-11-05
   inherit (pkgs) coc-yaml; # Added 2025-11-05
   inherit (pkgs) coc-yank; # Added 2025-11-05
+  inherit (pkgs) code-theme-converter; # Added 2025-11-08
   coinmon = throw "coinmon was removed since it was abandoned upstream"; # added 2024-03-19
   coffee-script = pkgs.coffeescript; # added 2023-08-18
   inherit (pkgs) concurrently; # added 2024-08-05
   inherit (pkgs) configurable-http-proxy; # added 2023-08-19
+  inherit (pkgs) conventional-changelog-cli; # Added 2025-11-08
   copy-webpack-plugin = throw "copy-webpack-plugin was removed because it is a JS library, so your project should lock it with a JS package manager instead."; # Added 2024-12-16
   inherit (pkgs) cordova; # added 2023-08-18
   create-cycle-app = throw "create-cycle-app has been removed because it is unmaintained and has issues installing with recent nodejs versions."; # Added 2025-11-01
@@ -140,6 +145,7 @@ mapAliases {
   dat = throw "dat was removed because it was broken"; # added 2023-08-21
   inherit (pkgs) degit; # added 2023-08-18
   inherit (pkgs) diagnostic-languageserver; # added 2024-06-25
+  inherit (pkgs) diff2html-cli; # Added 2025-11-08
   inherit (pkgs) dockerfile-language-server-nodejs; # added 2023-08-18
   inherit (pkgs) dotenv-cli; # added 2024-06-26
   eask = pkgs.eask; # added 2023-08-17
@@ -192,16 +198,19 @@ mapAliases {
   inherit (pkgs) javascript-typescript-langserver; # added 2023-08-19
   inherit (pkgs) js-beautify; # Added 2025-11-06
   inherit (pkgs) jshint; # Added 2025-11-06
+  inherit (pkgs) json-diff; # Added 2025-11-07
   inherit (pkgs) jsonplaceholder; # Added 2025-11-04
   inherit (pkgs) json-server; # Added 2025-11-06
   joplin = pkgs.joplin-cli; # Added 2025-11-02
   inherit (pkgs) kaput-cli; # added 2024-12-03
   karma = pkgs.karma-runner; # added 2023-07-29
+  inherit (pkgs) katex; # Added 2025-11-08
   keyoxide = pkgs.keyoxide-cli; # Added 2025-10-20
   leetcode-cli = self.vsc-leetcode-cli; # added 2023-08-31
   inherit (pkgs) lerna; # added 2025-02-12
   less = pkgs.lessc; # added 2024-06-15
   less-plugin-clean-css = pkgs.lessc.plugins.clean-css; # added 2024-06-15
+  inherit (pkgs) localtunnel; # Added 2025-11-08
   lodash = throw "lodash was removed because it provides no executable"; # added 2025-03-18
   lua-fmt = throw "'lua-fmt' has been removed because it has critical bugs that break formatting"; # Added 2025-11-07
   inherit (pkgs) lv_font_conv; # added 2024-06-28
@@ -231,6 +240,7 @@ mapAliases {
   }); # added 2024-10-04
   inherit (pkgs) npm-check-updates; # added 2023-08-22
   npm-merge-driver = throw "'npm-merge-driver' has been removed, since the upstream repo was archived on Aug 11, 2021"; # Added 2025-11-07
+  inherit (pkgs) nrm; # Added 2025-11-08
   ocaml-language-server = throw "ocaml-language-server was removed because it was abandoned upstream"; # added 2023-09-04
   orval = throw "orval has been removed because it was broken"; # added 2025-03-23
   parcel = throw "parcel has been removed because it was broken"; # added 2025-03-12

pkgs/development/node-packages/main-programs.nix

@@ -1,25 +1,20 @@
 # Use this file to add `meta.mainProgram` to packages in `nodePackages`.
 {
   # Packages that provide multiple executables where one is clearly the `mainProgram`.
-  "@antfu/ni" = "ni";
   "@microsoft/rush" = "rush";
 
   # Packages that provide a single executable.
   "@angular/cli" = "ng";
-  "@commitlint/cli" = "commitlint";
   aws-cdk = "cdk";
   cdk8s-cli = "cdk8s";
   clipboard-cli = "clipboard";
-  conventional-changelog-cli = "conventional-changelog";
   cpy-cli = "cpy";
-  diff2html-cli = "diff2html";
   fast-cli = "fast";
   fauna-shell = "fauna";
   fkill-cli = "fkill";
   grunt-cli = "grunt";
   gulp-cli = "gulp";
   jsonlint = "jsonlint";
-  localtunnel = "lt";
   poor-mans-t-sql-formatter-cli = "sqlformat";
   pulp = "pulp";
   purescript-language-server = "purescript-language-server";

pkgs/development/node-packages/node-packages.json

@@ -1,7 +1,5 @@
 [
   "@angular/cli"
-, "@antfu/ni"
-, "@commitlint/cli"
 , "@microsoft/rush"
 , "@tailwindcss/aspect-ratio"
 , "@tailwindcss/forms"
@@ -19,11 +17,8 @@
 , "coc-ltex"
 , "coc-tsserver"
 , "coc-ultisnips"
-, "code-theme-converter"
-, "conventional-changelog-cli"
 , "cpy-cli"
 , "dhcp"
-, "diff2html-cli"
 , "dotenv-vault"
 , "elasticdump"
 , "emoj"
@@ -41,14 +36,11 @@
 , "js-yaml"
 , "jsdoc"
 , "json"
-, "json-diff"
 , "json-refs"
 , "jsonlint"
-, "katex"
 , "lcov-result-merger"
 , "live-server"
 , "livedown"
-, "localtunnel"
 , "madoko"
 , "mathjax"
 , "multi-file-swagger"
@@ -56,7 +48,6 @@
 , "node-gyp-build"
 , "node2nix"
 , "np"
-, "nrm"
 , "peerflix"
 , "peerflix-server"
 , "poor-mans-t-sql-formatter-cli"
@@ -79,5 +70,4 @@
 , "vega-cli"
 , "vercel"
 , "wavedrom-cli"
-, "@yaegassy/coc-nginx"
 ]

pkgs/top-level/all-packages.nix

@@ -1202,8 +1202,6 @@ with pkgs;
 
   cgit-pink = callPackage ../applications/version-management/cgit/pink.nix { };
 
-  commitlint = nodePackages."@commitlint/cli";
-
   datalad = with python3Packages; toPythonApplication datalad;
 
   datalad-gooey = with python3Packages; toPythonApplication datalad-gooey;