mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-11-24 17:43:19 +01:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
101 lines
2.9 KiB
Nix
101 lines
2.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.litestream;
|
|
settingsFormat = pkgs.formats.yaml {};
|
|
in
|
|
{
|
|
options.services.litestream = {
|
|
enable = mkEnableOption "litestream";
|
|
|
|
package = mkOption {
|
|
description = lib.mdDoc "Package to use.";
|
|
default = pkgs.litestream;
|
|
defaultText = literalExpression "pkgs.litestream";
|
|
type = types.package;
|
|
};
|
|
|
|
settings = mkOption {
|
|
description = lib.mdDoc ''
|
|
See the [documentation](https://litestream.io/reference/config/).
|
|
'';
|
|
type = settingsFormat.type;
|
|
example = {
|
|
dbs = [
|
|
{
|
|
path = "/var/lib/db1";
|
|
replicas = [
|
|
{
|
|
url = "s3://mybkt.litestream.io/db1";
|
|
}
|
|
];
|
|
}
|
|
];
|
|
};
|
|
};
|
|
|
|
environmentFile = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = null;
|
|
example = "/run/secrets/litestream";
|
|
description = ''
|
|
Environment file as defined in <citerefentry>
|
|
<refentrytitle>systemd.exec</refentrytitle><manvolnum>5</manvolnum>
|
|
</citerefentry>.
|
|
|
|
Secrets may be passed to the service without adding them to the
|
|
world-readable Nix store, by specifying placeholder variables as
|
|
the option value in Nix and setting these variables accordingly in the
|
|
environment file.
|
|
|
|
By default, Litestream will perform environment variable expansion
|
|
within the config file before reading it. Any references to ''$VAR or
|
|
''${VAR} formatted variables will be replaced with their environment
|
|
variable values. If no value is set then it will be replaced with an
|
|
empty string.
|
|
|
|
<programlisting>
|
|
# Content of the environment file
|
|
LITESTREAM_ACCESS_KEY_ID=AKIAxxxxxxxxxxxxxxxx
|
|
LITESTREAM_SECRET_ACCESS_KEY=xxxxxxxxxxxxxxxxxxxxxxxxxxxxxx/xxxxxxxxx
|
|
</programlisting>
|
|
|
|
Note that this file needs to be available on the host on which
|
|
this exporter is running.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
environment.systemPackages = [ cfg.package ];
|
|
environment.etc = {
|
|
"litestream.yml" = {
|
|
source = settingsFormat.generate "litestream-config.yaml" cfg.settings;
|
|
};
|
|
};
|
|
|
|
systemd.services.litestream = {
|
|
description = "Litestream";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "networking.target" ];
|
|
serviceConfig = {
|
|
EnvironmentFile = mkIf (cfg.environmentFile != null) cfg.environmentFile;
|
|
ExecStart = "${cfg.package}/bin/litestream replicate";
|
|
Restart = "always";
|
|
User = "litestream";
|
|
Group = "litestream";
|
|
};
|
|
};
|
|
|
|
users.users.litestream = {
|
|
description = "Litestream user";
|
|
group = "litestream";
|
|
isSystemUser = true;
|
|
};
|
|
users.groups.litestream = {};
|
|
};
|
|
meta.doc = ./litestream.xml;
|
|
}
|