mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-11-14 03:36:04 +01:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
113 lines
2.7 KiB
Nix
113 lines
2.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
cfg = config.services.corosync;
|
|
in
|
|
{
|
|
# interface
|
|
options.services.corosync = {
|
|
enable = mkEnableOption "corosync";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.corosync;
|
|
defaultText = literalExpression "pkgs.corosync";
|
|
description = lib.mdDoc "Package that should be used for corosync.";
|
|
};
|
|
|
|
clusterName = mkOption {
|
|
type = types.str;
|
|
default = "nixcluster";
|
|
description = lib.mdDoc "Name of the corosync cluster.";
|
|
};
|
|
|
|
extraOptions = mkOption {
|
|
type = with types; listOf str;
|
|
default = [];
|
|
description = lib.mdDoc "Additional options with which to start corosync.";
|
|
};
|
|
|
|
nodelist = mkOption {
|
|
description = lib.mdDoc "Corosync nodelist: all cluster members.";
|
|
default = [];
|
|
type = with types; listOf (submodule {
|
|
options = {
|
|
nodeid = mkOption {
|
|
type = int;
|
|
description = lib.mdDoc "Node ID number";
|
|
};
|
|
name = mkOption {
|
|
type = str;
|
|
description = lib.mdDoc "Node name";
|
|
};
|
|
ring_addrs = mkOption {
|
|
type = listOf str;
|
|
description = lib.mdDoc "List of addresses, one for each ring.";
|
|
};
|
|
};
|
|
});
|
|
};
|
|
};
|
|
|
|
# implementation
|
|
config = mkIf cfg.enable {
|
|
environment.systemPackages = [ cfg.package ];
|
|
|
|
environment.etc."corosync/corosync.conf".text = ''
|
|
totem {
|
|
version: 2
|
|
secauth: on
|
|
cluster_name: ${cfg.clusterName}
|
|
transport: knet
|
|
}
|
|
|
|
nodelist {
|
|
${concatMapStrings ({ nodeid, name, ring_addrs }: ''
|
|
node {
|
|
nodeid: ${toString nodeid}
|
|
name: ${name}
|
|
${concatStrings (imap0 (i: addr: ''
|
|
ring${toString i}_addr: ${addr}
|
|
'') ring_addrs)}
|
|
}
|
|
'') cfg.nodelist}
|
|
}
|
|
|
|
quorum {
|
|
# only corosync_votequorum is supported
|
|
provider: corosync_votequorum
|
|
wait_for_all: 0
|
|
${optionalString (builtins.length cfg.nodelist < 3) ''
|
|
two_node: 1
|
|
''}
|
|
}
|
|
|
|
logging {
|
|
to_syslog: yes
|
|
}
|
|
'';
|
|
|
|
environment.etc."corosync/uidgid.d/root".text = ''
|
|
# allow pacemaker connection by root
|
|
uidgid {
|
|
uid: 0
|
|
gid: 0
|
|
}
|
|
'';
|
|
|
|
systemd.packages = [ cfg.package ];
|
|
systemd.services.corosync = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
serviceConfig = {
|
|
StateDirectory = "corosync";
|
|
StateDirectoryMode = "0700";
|
|
};
|
|
};
|
|
|
|
environment.etc."sysconfig/corosync".text = lib.optionalString (cfg.extraOptions != []) ''
|
|
COROSYNC_OPTIONS="${lib.escapeShellArgs cfg.extraOptions}"
|
|
'';
|
|
};
|
|
}
|