mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-11-12 10:43:16 +01:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
79 lines
2.1 KiB
Nix
79 lines
2.1 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.services.spotifyd;
|
|
toml = pkgs.formats.toml { };
|
|
warnConfig =
|
|
if cfg.config != "" then
|
|
lib.trace "Using the stringly typed .config attribute is discouraged. Use the TOML typed .settings attribute instead."
|
|
else
|
|
lib.id;
|
|
spotifydConf =
|
|
if cfg.settings != { } then
|
|
toml.generate "spotify.conf" cfg.settings
|
|
else
|
|
warnConfig (pkgs.writeText "spotifyd.conf" cfg.config);
|
|
in
|
|
{
|
|
options = {
|
|
services.spotifyd = {
|
|
enable = lib.mkEnableOption "spotifyd, a Spotify playing daemon";
|
|
|
|
config = lib.mkOption {
|
|
default = "";
|
|
type = lib.types.lines;
|
|
description = ''
|
|
(Deprecated) Configuration for Spotifyd. For syntax and directives, see
|
|
<https://docs.spotifyd.rs/config/File.html>.
|
|
'';
|
|
};
|
|
|
|
settings = lib.mkOption {
|
|
default = { };
|
|
type = toml.type;
|
|
example = {
|
|
global.bitrate = 320;
|
|
};
|
|
description = ''
|
|
Configuration for Spotifyd. For syntax and directives, see
|
|
<https://docs.spotifyd.rs/config/File.html>.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
assertions = [
|
|
{
|
|
assertion = cfg.config == "" || cfg.settings == { };
|
|
message = "At most one of the .config attribute and the .settings attribute may be set";
|
|
}
|
|
];
|
|
|
|
systemd.services.spotifyd = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
wants = [ "network-online.target" ];
|
|
after = [
|
|
"network-online.target"
|
|
"sound.target"
|
|
];
|
|
description = "spotifyd, a Spotify playing daemon";
|
|
environment.SHELL = "/bin/sh";
|
|
serviceConfig = {
|
|
ExecStart = "${pkgs.spotifyd}/bin/spotifyd --no-daemon --cache-path /var/cache/spotifyd --config-path ${spotifydConf}";
|
|
Restart = "always";
|
|
RestartSec = 12;
|
|
DynamicUser = true;
|
|
CacheDirectory = "spotifyd";
|
|
SupplementaryGroups = [ "audio" ];
|
|
};
|
|
};
|
|
};
|
|
|
|
meta.maintainers = [ lib.maintainers.anderslundstedt ];
|
|
}
|