mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-11-10 17:54:53 +01:00
ab49e37a02
This adds foundational functionality for nixos-facter hardware detection: - lib.nix: Internal helper functions for querying facter reports - hasCpu/hasAmdCpu/hasIntelCpu: CPU vendor detection - collectDrivers: Extract driver_modules from hardware entries - toZeroPaddedHex: Format USB device IDs (for fingerprint matching) - system.nix: Auto-detect nixpkgs.hostPlatform from facter report Automatically sets the correct platform (x86_64-linux, aarch64-linux, etc.) based on the hardware report, reducing manual configuration. This builds on the base infrastructure added in PR #450303 and provides the foundation for upcoming hardware detection modules (boot, networking, graphics, etc.). Part of the incremental upstreaming effort from: https://github.com/nix-community/nixos-facter-modules
60 lines
1.3 KiB
Nix
60 lines
1.3 KiB
Nix
# Internal library functions for hardware.facter modules
|
|
# Eventually we can think about moving this under lib/
|
|
# These are facter-specific helpers for querying nixos-facter reports
|
|
lib:
|
|
let
|
|
|
|
inherit (lib) assertMsg;
|
|
|
|
# Query if a facter report contains a CPU with the given vendor name
|
|
hasCpu =
|
|
name:
|
|
{
|
|
hardware ? { },
|
|
...
|
|
}:
|
|
let
|
|
cpus = hardware.cpu or [ ];
|
|
in
|
|
assert assertMsg (hardware != { }) "no hardware entries found in the report";
|
|
assert assertMsg (cpus != [ ]) "no cpu entries found in the report";
|
|
builtins.any (
|
|
{
|
|
vendor_name ? null,
|
|
...
|
|
}:
|
|
assert assertMsg (vendor_name != null) "detail.vendor_name not found in cpu entry";
|
|
vendor_name == name
|
|
) cpus;
|
|
|
|
# Extract all driver_modules from a list of hardware entries
|
|
collectDrivers = list: lib.catAttrs "driver_modules" list;
|
|
|
|
# Convert number to zero-padded 4-digit hex string (for USB device IDs)
|
|
toZeroPaddedHex =
|
|
n:
|
|
let
|
|
hex = lib.toHexString n;
|
|
len = builtins.stringLength hex;
|
|
in
|
|
if len == 1 then
|
|
"000${hex}"
|
|
else if len == 2 then
|
|
"00${hex}"
|
|
else if len == 3 then
|
|
"0${hex}"
|
|
else
|
|
hex;
|
|
in
|
|
{
|
|
inherit
|
|
hasCpu
|
|
collectDrivers
|
|
toZeroPaddedHex
|
|
;
|
|
|
|
hasAmdCpu = hasCpu "AuthenticAMD";
|
|
hasIntelCpu = hasCpu "GenuineIntel";
|
|
|
|
}
|